Quando si installa una nuova applicazione in OS X, si tratta di solito di un file DMG che si deve montare, poi espellere ed eliminare. E’ possibile però semplificare il processo, espellendo l’immagine DMG e eliminandolo in un colpo solo.
Ecco come creare questo semplice servizio per Automator:
- Aprire l’applicazione Automator e selezionare “Service“;
- Modificare i primi due menu a discesa per ricevere “Nessun ingresso” dal “Finder”;
- Nella barra laterale di sinistra, copiare lo script “Esegui AppleScript” nel riquadro di destra. Copiare il codice riportato di seguito nella casella;
- Salvare il servizio come si desidera (come "Espulsione & Elimina DMG") e chiudere Automator.
tell application "Finder"
set selection_list to selection
if (count selection_list) < 1 then
display dialog ¬
"Please select a volume mounted from a disk image." with title ¬
"No Selection Found" with icon stop ¬
buttons ["OK"] default button 1
return
end if
set my_selection to item 1 of selection_list
set my_kind to kind of my_selection
set my_name to name of my_selection
if my_kind is not "Volume" then
display dialog ¬
"Please select a volume mounted from a disk image file." with title ¬
"Selection is not a Disk Image" with icon stop ¬
buttons ["OK"] default button 1
return
end if
set volume_list to paragraphs of (do shell script "hdiutil info | grep ^/dev/disk | grep -o '/Volumes/.*'")
set source_list to paragraphs of (do shell script "hdiutil info | grep ^image'-'alias | grep -o '/.*'")
set match_found to false
repeat with v from 1 to (count volume_list)
if "/Volumes/" & my_name = item v of volume_list then
set match_found to true
exit repeat
end if
end repeat
if match_found is not equal to true then
display dialog ¬
"The selected volume does not appear to be a Disk Image." with title ¬
"Could not find Disk Image" with icon stop ¬
buttons ["OK"] default button 1
return
else
set my_source to POSIX file (item v of source_list) as alias
move my_source to the trash
eject my_selection
—reveal my_source
end if
end tell
Ora, quando hai finito di utilizzare un file DMG, è sufficiente cliccare su di esso, quindi andare su "Finder" -> "Servizi" -> "Espellere & Elimina DMG" per espellere l'immagine ed eliminare il DMG con un solo clic. Se davvero si vuole fare molto più in fretta, si può andare in "Preferenze di Sistema" -> "Tastiera" -> "Scorciatoie da tastiera" e dare al servizio una comoda da scorciatoia tastiera. Nota che questo non funziona se si seleziona un DMG nella barra laterale del Finder, è necessario selezionarlo in una finestra del Finder attuale (o sul desktop).
Via | Lifehacker